Les AddActions! :D

[RaptorJoe]

Bon, ceci est très désintéressé de ma part, mais Yourry a dit qu'il fallait faire vivre le forum donc je continue sur ma lancée :p

PS: ce sujet concernera les petits problèmes rencontrés face aux AddActions

Voici la réponse à ton problème:

Code : Tout sélectionner

_valise = _this select 0;
_id = _this select 2;

//sert à supprimer l'action "prendre la valise"
_valise removeAction _id;

//Utilisation d'une fonction Multiplayer-Framework. Attention pour que cela fonctionne, il faut poser le module de fonction (F7) sur la carte !!!!!
    //------> Cette fonction permet d'envoyer à tous les joueurs le code ci-dessous:
    _nic = [nil,nil,rSPAWN,[],{
        hint"Une valise a été trouvée";
        playSound "radionoise1";
        extrac sideChat "Valise trouvée";
        sleep 3;
        obj1 setTaskState "SUCCEEDED";
        nul=[objNull, objNull, obj1, "SUCCEEDED"] execVM "CA\Modules\MP\data\scriptCommands\taskHint.sqf";
    }] call RE;


//supprime la valise
deleteVehicle valise;                    

Il te faut poser sur la carte le module de fonction (F7) sinon le truc "call RE" ne fonctionne pas bien !!!!

ps: pense à sauvegarder en UTF-8 pour conserver les accents.

Lors d'une mission 'spéciale' nommée 'bouclier blindé' où mes collègues russophiles pensaient avoir à affronter des bataillons entiers de blindés, j'ai ajouté un AddAction à un générateur de secours. Here the code used, basé évidemment sur les précisions du docteur Yourry :

Code : Tout sélectionner

_rem = _this select 0;
_id = _this select 2;

//sert à supprimer l'action "demarrer"
_rem removeAction _id;

//Utilisation d'une fonction Multiplayer-Framework. Attention pour que cela fonctionne, il faut poser le module de fonction (F7) sur la carte !!!!!
    //------> Cette fonction permet d'envoyer à tous les joueurs le code ci-dessous:
    _nic = [nil,nil,rSPAWN,[],{
    sleep 1;
    rem say3D "demarreur";
    sleep 6;
    rem say3D "engine_35s";
    sleep 8;
    ber say3D "zombiewalk";
    hz_hunt_distance= 300;
    sleep 5;
    ber1 say3D "mindlesszomb";
    ber2 say3D "engine_35s";
    sleep 25;
    ber2 say3D "engine_35s";
    sleep 25;
    rem say3D "arretmoteur";
    nul=[feu1,4,time,false,false] spawn BIS_Effects_Burn;
    sleep 15;
    hz_hunt_distance= 30;
    }] call RE;
  

Le tout fonctionne nickel à un détail près: l'action ne s'efface pas, et est encore disponible pour tous les autres joueurs. Le removeaction doit-il faire partie de la fonction CALL RE? Merci d'avance de votre réponse

[=[TTK]= Yourry]

Non le "removeAction" n'a pas besoin d'être dans le call RE.
Je viens de faire le teste en solo sur l'éditeur, l'action se supprime bien via cette commande et telle qu'elle est écrite dans le script.
L'action disparaît-elle uniquement pour la personne qui fait l'action où vraiment pour personne ?!?

[RaptorJoe]

Et bien un ami a lancé l'action, et cette dernière a bien disparue pour lui. Une trentaine de zombies plus tard, j'ai remarqué que je pouvais faire moi aussi l'action... Et pour tester j'ai essayé de la lancer. Résultat, trente zombies de plus. Le removeaction n'a donc pas fonctionné (je devrais faire des tests plus poussées avec mes amis tout de même, ça me paraît étrange cette histoire)

[=[TTK]= Yourry]

Et bien un ami a lancé l'action, et cette dernière a bien disparue pour lui. Une trentaine de zombies plus tard, j'ai remarqué que je pouvais faire moi aussi l'action

Effectivement c'est étrange et peut être une particularité des parties Hostées. On pourrait mettre le removeAction dans le call RE, qui aurait pour conséquence d'envoyer la commande à tous les joueurs. Cependant, pour un joueur qui se connecte en cours de partie, l'action ne sera pas supprimé car le call RE est instantané et éphémère.

Il y ' a une autre solution qui est beaucoup utilisée, c'est de mettre une condition. Dans la commande du addaction, tu peux mettre une condition. L'action ne sera disponible que si la condition est remplie.
Il nous suffira dans le script de l'action de passer à faux notre condition pour que toutes actions soient enlevées.

Voici le wiki fr pour t'aider:
http://arma2-wiki.fr/addAction

Dans notre cas, la commande de l'action se complexifie (pour connaitre le sens des trucs en plus, je t’invite à lire le wiki):

Code : Tout sélectionner

object_qui_avoir_laction addAction ["Mon action", "monscript.sqf", [], 0,false, true, "", " isNil ""action_realisee"" "];    

Et le script :

Code : Tout sélectionner

_rem = _this select 0;
_id = _this select 2;

//sert à supprimer l'action "demarrer"
    _rem removeAction _id;

////////////////////
//Variable qui bloquera l'action
    action_realisee = true;
    publicVariable"action_realisee";
////////////////////


//Utilisation d'une fonction Multiplayer-Framework. Attention pour que cela fonctionne, il faut poser le module de fonction (F7) sur la carte !!!!!
    //------> Cette fonction permet d'envoyer à tous les joueurs le code ci-dessous:
    _nic = [nil,nil,rSPAWN,[],{
        sleep 1;
        rem say3D "demarreur";
        sleep 6;
        rem say3D "engine_35s";
        sleep 8;
        ber say3D "zombiewalk";
        hz_hunt_distance= 300;
        sleep 5;
        ber1 say3D "mindlesszomb";
        ber2 say3D "engine_35s";
        sleep 25;
        ber2 say3D "engine_35s";
        sleep 25;
        rem say3D "arretmoteur";
        nul=[feu1,4,time,false,false] spawn BIS_Effects_Burn;
        sleep 15;
        hz_hunt_distance= 30;
    }] call RE;
    

[RaptorJoe]

Après la fonte de ma carte graphique et de mon disque dur, je suis de retour, toujours près à souffrir (et à aimer ça en plus).

Donc pour te répondre Yourry, j'ai testé le code que tu m'as donné ci-dessus, et j'ai remarqué que... ça marchait pas bien chez moi, je sais pas pourquoi. Je l'ai assigné à un véhicule, et je pouvais le déclencher autant de fois que possible, mais bon, j'ai du faire une erreur quelque part. Je referais ça de nouveau je pense, c'est tellement bien les Addactions x)

[=[TTK]= Yourry]

Oui c'est normale vu la façon dont est écrit le code ci-dessus.
Pour que cela fonctionne comme tu veux et n'important quand (j'aurais du l'écrire dès le début comme ça):

Code : Tout sélectionner

object_qui_avoir_laction addAction ["Mon action", "monscript.sqf", [], 0,false, true, "", " isNil{_this getVariable""action_realisee""} "];     

Et l'autre :

Code : Tout sélectionner

_rem = _this select 0;
_id = _this select 2;

//sert à supprimer l'action "demarrer"
    _rem removeAction _id;

////////////////////
//Variable qui bloquera l'action
    _rem setVariable["action_realisee",true,true];
////////////////////


//Utilisation d'une fonction Multiplayer-Framework. Attention pour que cela fonctionne, il faut poser le module de fonction (F7) sur la carte !!!!!
    //------> Cette fonction permet d'envoyer à tous les joueurs le code ci-dessous:
    _nic = [nil,nil,rSPAWN,[],{
        sleep 1;
        rem say3D "demarreur";
        sleep 6;
        rem say3D "engine_35s";
        sleep 8;
        ber say3D "zombiewalk";
        hz_hunt_distance= 300;
        sleep 5;
        ber1 say3D "mindlesszomb";
        ber2 say3D "engine_35s";
        sleep 25;
        ber2 say3D "engine_35s";
        sleep 25;
        rem say3D "arretmoteur";
        nul=[feu1,4,time,false,false] spawn BIS_Effects_Burn;
        sleep 15;
        hz_hunt_distance= 30;
    }] call RE;
      

Et voilà chef, à vot' service !

[RaptorJoe]

Merci beaucoup grand chef Yourry! Malheureusement la mission que j'avais et qui utilisais ce code n'est plus, mort de mon pc oblige, mais je m'en servirais très prochainement dans de futures missions! Et évidemment je te tiendrais au courant